Circular reference and attributes.

Moved from https://github.com/fsharp/fsharp/issues/565

Repro steps

Paste the following code in FSI

open System

[<AttributeUsage(AttributeTargets.Property)>]
type MyAttribute() =
    inherit Attribute()
    member this.Foo () =
        new MyClass(1)
and MyClass(someValue) =
    [<MyAttribute()>]
    member this.SomeValue : int = someValue
;;

Expected behavior

It would compile to

type MyAttribute =
  class
    new : unit -> MyAttribute
    member Foo : unit -> MyClass
  end
and MyClass =
  class
    new : someValue:int -> MyClass
    member SomeValue : int
  end

Actual behavior

      [<MyAttribute()>]
  ------^^^^^^^^^^^

stdin(90,7): error FS0848: A custom attribute must invoke an object constructor

Known workarounds

Do it in C#.

Related information

Ran in fsi

Microsoft (R) F# Interactive version 14.0.23413.0

And in Visual Studio 2015 Update 2 with using a DLL with .NET 4.6.1, and the 4.4.0.0 F# Runtime.

This is done on a Windows 8.1 machine, but can reproduce on a Windows 10 (latest patches, until the one from 4/12/2016, non-Insider branch).

Use case:

namespace Test

open System
open System.ComponentModel.DataAnnotations

[<AttributeUsage(AttributeTargets.Property, AllowMultiple = false, Inherited = true)>]
type MyAttribute() =
    class
    inherit ValidationAttribute ()

    override this.IsValid (value: Object, validationContext: ValidationContext) =
        match validationContext.ObjectInstance with
        | :? MyClass as item ->
            // TODO more validation
            ValidationResult.Success
        | _ ->
            new ValidationResult("No no no")
    end
and MyClass(someValue) =
    [<MyAttribute>]
    member this.SomeValue : int = someValue

[kid]

As a workaround, you could define your types in a signature file first, this seems to work:

Foo.fsi

namespace Foo

open System

[<AttributeUsage(AttributeTargets.Property)>]
type MyAttribute =
    inherit System.Attribute

    new : unit -> MyAttribute

    member Foo : unit -> MyClass

and MyClass =
    new : someValue : int -> MyClass

    [<MyAttribute()>]
    member SomeValue : int

Foo.fs

namespace Foo

open System

[<AttributeUsage(AttributeTargets.Property)>]
type MyAttribute() =
    inherit Attribute()

    member this.Foo () =
        new MyClass(1)

and MyClass(someValue) =
    // [<MyAttribute()>] -> specified in the fsi, still appears in compiled code
    member this.SomeValue : int = someValue

[dsyme]

Note this is a good test case for https://github.com/fsharp/FSharpLangDesign/blob/master/RFCs/FS-1009-mutually-referential-types-and-modules-single-scope.md

The code would become the more pleasant:

namespace rec Test

open System
open System.ComponentModel.DataAnnotations

[<AttributeUsage(AttributeTargets.Property, AllowMultiple = false, Inherited = true)>]
type MyAttribute() =
    inherit ValidationAttribute ()

    override this.IsValid (value: Object, validationContext: ValidationContext) =
        match validationContext.ObjectInstance with
        | :? MyClass as item ->    ValidationResult.Success
        | _ ->     new ValidationResult("No no no")

type MyClass(someValue) =
    [<MyAttribute()>]
    member this.SomeValue : int = someValue