Cannot use asyncResult computation expressions in resolvers

Description

I am trying to use asyncResult computation expressions (from the excellent FsToolkit.ErrorHandling) in an AsyncField. This results in a run-time error when building the schema.

Repro steps

Here is a simplified script that shows the problem. You can run it with dotnet fsi ./Repro.fsx

#r "nuget: FSharp.Data.GraphQL.Server, 1.0.7"
#r "nuget: FsToolkit.ErrorHandling, 2.2.0"

open System
open FSharp.Data.GraphQL

type Product =
  {
    ID : Guid
    Name : string
    Weight : int
  }

module Schema =

  open FsToolkit.ErrorHandling
  open FSharp.Data.GraphQL.Types

  let private tryParseGuid (x : string) =
    match System.Guid.TryParse x with
    | (true, g) -> Ok g
    | _ -> Error (sprintf "Invalid GUID: %s" x)

  let productType =
    Define.Object
      (
        "Product",
        [
          Define.Field ("id", ID, fun ctx x -> x.ID)
          Define.Field ("name", String, fun ctx x -> x.Name)
          Define.Field ("weight", Int, fun ctx x -> x.Weight)
        ]
      )

  let queryType =
    Define.Object
      (
        name = "Query",
        fields =
          [
            Define.AsyncField
              (
                "product",
                Nullable productType,
                "Fetch a product by ID",
                [
                  Define.Input ("id", ID)
                ],
                (fun ctx (x : Map<Guid, Product>) ->
                  async {
                    let! result =
                      asyncResult {
                        let! id =
                          ctx.Args
                          |> Map.tryFind "id"
                          |> Result.requireSome "Missing id argument"
                          |> Result.bind (fun x ->
                            match x with
                            | :? System.Guid as g -> Ok g
                            | :? System.String as s -> tryParseGuid s
                            | x -> Error (sprintf "Invalid id: %A" x)
                          )

                        let product = Map.tryFind id x

                        return product
                      }

                    match result with
                    | Ok x ->
                      return x
                    | Error message ->
                      return failwith message
                  })
              )
          ]
      )

let schema = Schema (Schema.queryType)

let executor = Executor (schema)

let crateOfOranges =
  {
    ID = Guid.NewGuid ()
    Name = "Crate of Oranges"
    Weight = 123
  }

let data =
  Map.empty
  |> Map.add crateOfOranges.ID crateOfOranges

async {
  let plan =
    Parser.parse "query product($id : ID!) { product(id: $id) { id, name, weight } }"

  let variables =
    Map.empty
    |> Map.add "id" (crateOfOranges.ID |> string :> obj)

  let! result =
    executor.AsyncExecute (plan, data, variables)

  printfn "%A" result
}
|> Async.RunSynchronously

Expected behavior

Output like:

{ Content =
           Direct
             (seq
                [[documentId, 303956704];
                 [data, { product: { id: d63d5b1a-31ee-4c61-a68c-06c7b576afcc,
			name: "Crate of Oranges",
			weight: 123 } }]],
              [])
  Metadata = map [] }

Actual behavior

Run-time error related to quotations. I’m not sure what’s going on since my code doesn’t appear to use quotations!

System.InvalidOperationException: Could not bind function AsyncResultBuilder.Source in type FsToolkit.ErrorHandling.AsyncResultCEExtensions
   at Microsoft.FSharp.Quotations.PatternsModule.fail@1118[a](Type ty, String nm, Unit unitVar0) in F:\workspace\_work\1\s\src\fsharp\FSharp.Core\quotations.fs:line 1118
   at Microsoft.FSharp.Quotations.PatternsModule.bindModuleFunctionWithCallSiteArgs$cont@1110(Type ty, String nm, Type[] argTypes, Type[] tyArgs, Unit unitVar) in F:\workspace\_work\1\s\src\fsharp\FSharp.Core\quotations.fs:line 1169
   at Microsoft.FSharp.Quotations.PatternsModule.bindModuleFunctionWithCallSiteArgs(Type ty, String nm, FSharpList`1 argTypes, FSharpList`1 tyArgs) in F:\workspace\_work\1\s\src\fsharp\FSharp.Core\quotations.fs:line 1105
   at [e-mail](FSharpList`1 argTypes, FSharpList`1 tyargs) in F:\workspace\_work\1\s\src\fsharp\FSharp.Core\quotations.fs:line 1576
   at [e-mail](FSharpList`1 argTypes, FSharpList`1 tyargs) in F:\workspace\_work\1\s\src\fsharp\FSharp.Core\quotations.fs:line 1636
   at [e-mail](BindingEnv env) in F:\workspace\_work\1\s\src\fsharp\FSharp.Core\quotations.fs:line 1501
...

Known workarounds

Write in async computation expressions only. This can lead to less readable code in some situations.

                  async {
                    let id =
                      ctx.Args
                      |> Map.find "id"
                      |> (
                        function
                        | :? System.Guid as g -> g
                        | :? System.String as s -> System.Guid.Parse s
                        | x -> failwithf "Invalid id: %A" x
                      )

                    let product = Map.tryFind id x

                    return product
                  })

I would appreciate any work-arounds that allow the use of asyncResult.

Related information

• Operating system: Ubuntu 20.04
• Nuget packages: FSharp.Data.GraphQL.Server (1.0.7), FsToolkit.ErrorHandling (2.2)
• .NET Runtime, CoreCLR or Mono Version

dotnet --version
5.0.103

[jberzy]

This will work:

#r "nuget: FSharp.Data.GraphQL.Server, 1.0.7"
#r "nuget: FsToolkit.ErrorHandling, 2.2.0"

open System
open FSharp.Data.GraphQL

type Product =
  {
    ID : Guid
    Name : string
    Weight : int
  }

module Schema =

  open FsToolkit.ErrorHandling
  open FSharp.Data.GraphQL.Types

  let private tryParseGuid (x : string) =
    match System.Guid.TryParse x with
    | (true, g) -> Ok g
    | _ -> Error (sprintf "Invalid GUID: %s" x)

  let productType =
    Define.Object
      (
        "Product",
        [
          Define.Field ("id", ID, fun ctx x -> x.ID)
          Define.Field ("name", String, fun ctx x -> x.Name)
          Define.Field ("weight", Int, fun ctx x -> x.Weight)
        ]
      )

  let getProduct (ctx: ResolveFieldContext) x =
    asyncResult {
        let! id =
          ctx.Args
          |> Map.tryFind "id"
          |> Result.requireSome "Missing id argument"
          |> Result.bind (fun x ->
            match x with
            | :? System.Guid as g -> Ok g
            | :? System.String as s -> tryParseGuid s
            | x -> Error (sprintf "Invalid id: %A" x)
          )
        let product = Map.tryFind id x
        return product
      }


  let queryType =
    Define.Object
      (
        name = "Query",
        fields =
          [
            Define.AsyncField
              (
                "product",
                Nullable productType,
                "Fetch a product by ID",
                [
                  Define.Input ("id", ID)
                ],
                (fun ctx (x : Map<Guid, Product>) ->
                  async {
                    let! result = getProduct ctx x
                    match result with
                    | Ok x ->
                      return x
                    | Error message ->
                      return failwith message
                  })
              )
          ]
      )

let schema = Schema (Schema.queryType)

let executor = Executor (schema)

let crateOfOranges =
  {
    ID = Guid.NewGuid ()
    Name = "Crate of Oranges"
    Weight = 123
  }

let data =
  Map.empty
  |> Map.add crateOfOranges.ID crateOfOranges

async {
  let plan =
    Parser.parse "query product($id : ID!) { product(id: $id) { id, name, weight } }"

  let variables =
    Map.empty
    |> Map.add "id" (crateOfOranges.ID |> string :> obj)

  let! result =
    executor.AsyncExecute (plan, data, variables)

  printfn "%A" result
}
|> Async.RunSynchronously

[xperiandri]

Yes, they are. Allow to use directly