Wrappers not generated with KSP when using embedAndSignAppleFrameworkForXcode

This is an issue that got mixed with #49.

User @yamakentoc reports that this gradle config doesn’t result in wrapper classes being generated.

// HogeHogeHoge/shared/build.gradle.kts
// kotlin version: 1.7,0

val ktorVersion = "2.0.1"
val kotlinCoroutineVersion = "1.6.3"

plugins {
    kotlin("multiplatform")
    id("com.android.library")
    id("com.google.devtools.ksp") version "1.7.0-1.0.6"
    id("com.futuremind.koru").version("0.11.0")
    kotlin("plugin.serialization")
}

kotlin {
    android()

    listOf(
        iosX64(),
        iosArm64(),
        iosSimulatorArm64()
    ).forEach {
        it.binaries.framework {
            baseName = "HogeHogeHoge"
        }
    }

    sourceSets {
        val commonMain by getting {
            dependencies {
                //Coroutines
                implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:$kotlinCoroutineVersion-native-mt")
                //Network
                implementation("io.ktor:ktor-client-core:$ktorVersion")
                implementation("io.ktor:ktor-client-serialization:$ktorVersion")
                // JSON Serialization
                implementation("io.ktor:ktor-client-content-negotiation:$ktorVersion")
                implementation("io.ktor:ktor-serialization-kotlinx-json:$ktorVersion")
                // client mock
                implementation("io.ktor:ktor-client-mock:$ktorVersion")
                // koru
                implementation("com.futuremind:koru:0.11.1")
                // firebase
                implementation("dev.gitlive:firebase-auth:1.6.1")
            }
        }

        val androidMain by getting {
            dependencies {
                //Network
                implementation("io.ktor:ktor-client-okhttp:$ktorVersion")
            }
        }
        val commonTest by getting {
            dependencies {
                implementation(kotlin("test-common"))
                implementation(kotlin("test-annotations-common"))
            }
        }

        val iosX64Main by getting
        val iosArm64Main by getting
        val iosSimulatorArm64Main by getting
        val iosMain by creating {
            dependsOn(commonMain)
            iosX64Main.dependsOn(this)
            iosArm64Main.dependsOn(this)
            iosSimulatorArm64Main.dependsOn(this)
            dependencies {
                //Network
                implementation("io.ktor:ktor-client-darwin:$ktorVersion")
            }
        }
    }
}

android {
    compileSdk = 31
    sourceSets["main"].manifest.srcFile("src/androidMain/AndroidManifest.xml")
    defaultConfig {
        minSdk = 27
        targetSdk = 31
    }
}

koru {
    nativeSourceSetNames = listOf("iosMain")
}

[yamakentoc]

gradlew runs when build with Xcode, so it may be affected

[micHar]

I assume that kapt working and ksp not for your setup has something to do with the gradle task that you use. In the example repo I build xcframework with gradle assembleXCFramework and it seems to pick up the ksp step. gradle shared:build or gradle shared:assemble should be fine, too.

The code looks fine to me. Not sure how operator fun will behave, but if kapt works, ksp will probably, too. Will add tests for that, too.