Applying plugin to Gradle KTS project fails

I am creating a project using Gradle 6.5 and the Kotlin DSL. When I add the appengine plugin to my :api-server module I get this error:

An exception occurred applying plugin request [id: 'com.google.cloud.tools.appengine', version: '2.2.0', artifact: 'com.google.cloud.tools:appengine-gradle-plugin:2.2.0']
> Failed to apply plugin [class 'com.google.cloud.tools.gradle.appengine.standard.AppEngineStandardPlugin']
   > Task with name 'assemble' not found in project ':api-server'.

It looks like the plugin is trying to access the assemble task before it’s created. My plugins block looks like this:

plugins {
    kotlin("jvm")
    kotlin("plugin.serialization") version "1.3.72"
    id("com.google.cloud.tools.appengine") version "2.2.0"
    application
    war
}

Changing the plugins order doesn’t change the result.

PS: I am using a resolutionStrategy in my settings.gradle.kts to be able to reference the plugin — not that it has anything to do with the issue at hand:

pluginManagement {
    resolutionStrategy {
        eachPlugin {
            if (requested.id.id == "com.google.cloud.tools.appengine") {
                useModule("com.google.cloud.tools:appengine-gradle-plugin:${requested.version}")
            }
        }
    }
}

[rock3r]

For anyone else having issues with the plugin with the Kotlin DSL, and stumbling on this issue, here’s the current workaround:

plugins {
    kotlin("jvm")
    application
    war
}

buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath("com.google.cloud.tools:appengine-gradle-plugin:2.2.0")
    }
}

// Note: the AppEngine plugin currently does not work when applied using the
// plugins DSL, so we need to use the old-school way
apply(plugin = "com.google.cloud.tools.appengine")

configure<AppEngineStandardExtension> {
    deploy {
        projectId = "[TODO]"
        version = "[TODO]"
    }
}

tasks {
    val run by registering {
        dependsOn(named("appengineRun"))
    }
}

[loosebazooka]

Agree, there’s some work to be done here to bring things up to date.