dsl-testing :: javaposse.jobdsl.dsl.DslScriptException with OrganizationFolder

• Jenkins version ‘2.222.4’

• Plugin version ‘2.7.0’

Description

trying to establish testing for our job-dsl scripts we are running into issues with plugin bitbucket-branch-source. Using the job-dsl playground http://job-dsl.herokuapp.com/ with the following snippet we see the very same exception we get in our test-setup.

job-dsl snippet

organizationFolder('foo') {
    displayName('Foobar')

    organizations {
        bitbucket {
            serverUrl('https://stash.foobar.com')
            repoOwner('foo')
            credentialsId('stash-token')

            traits {
                sourceWildcardFilter {
                    includes('sample-project')
                    excludes('')
                }
            }
        }
    }
}

exception

javaposse.jobdsl.dsl.DslScriptException: (script, line 5) No signature of method: javaposse.jobdsl.dsl.helpers.workflow.ScmNavigatorsContext.bitbucket() is applicable for argument types: (script$_run_closure1$_closure2$_closure3) values: [script$_run_closure1$_closure2$_closure3@756dbb50]

[jam01]

Did you happen to solve this? Seeing the same issue with gitea, and wondering if it might be related.

[pniederlag]

Working Example

#!/usr/bin/env groovy
organizationFolder('example-org-folder') {
    displayName('Org Folder')
    description('automatic Jenkinsfile processing for org folder')
    organizations {
        bitbucket {
            credentialsId('my-credential-id')
            repoOwner('XYZ')
            serverUrl('https://fancy.example.com')
            traits {
              // - nonsense, due to traits with same name in different scopes, see configure block below
            }
        }
    }
    //projectFactories {
    //  workflowMultiBranchProjectFactory {
    //    scriptPath('Jenkinsfile')
    //  }
    //}
    orphanedItemStrategy {
        discardOldItems {
            daysToKeep(7)
            numToKeep(3)
        }
    }
    // discover Branches (workaround due to JENKINS-46202)
    configure { node ->
        // node represents <jenkins.branch.OrganizationFolder>
        def traits = node / 'navigators' / 'com.cloudbees.jenkins.plugins.bitbucket.BitbucketSCMNavigator' / 'traits'
        traits << 'com.cloudbees.jenkins.plugins.bitbucket.BranchDiscoveryTrait' {
           strategyId(3) // detect all branches
        }
        traits << 'com.cloudbees.jenkins.plugins.bitbucket.OriginPullRequestDiscoveryTrait' {
          strategyId(1)
        }
        traits << 'com.cloudbees.jenkins.plugins.bitbucket.TagDiscoveryTrait' {

        }
        traits << 'jenkins.plugins.git.traits.CloneOptionTrait' {
          // we must add something else than only noTags(false) in order to get it working
          'extension'(class: 'hudson.plugins.git.extensions.impl.CloneOption') {
            noTags(false)
            honorRefspec(false)
            timeout("15")
            shallow(false)
            reference("")
            depth(0)
          }
        }

        // Set child scan triggers to 15 minutes
        node / 'properties' << 'jenkins.branch.OrganizationChildTriggersProperty' {
          templates {
            'com.cloudbees.hudson.plugins.folder.computed.PeriodicFolderTrigger' {
              spec('H/5 * * * *')
              interval('900000')
            }
          }
        }

        // Add build strategies
        node / 'buildStrategies' << 'jenkins.branch.buildstrategies.basic.AllBranchBuildStrategyImpl' {
          strategies {
            'jenkins.branch.buildstrategies.basic.AnyBranchBuildStrategyImpl' {
              strategies {
                'jenkins.branch.buildstrategies.basic.TagBuildStrategyImpl' {
                  atLeastMillis(-1)
                  atMostMillis(604800000)
                }
                'jenkins.branch.buildstrategies.basic.BranchBuildStrategyImpl' {}
              }
            }
            'jenkins.branch.buildstrategies.basic.SkipInitialBuildOnFirstBranchIndexing' {}
          }
        }
    }
    //properties {
      //organizationChildTriggersProperty {
      //  periodicFolderTrigger {
      //    interval("15m")
      //  }
      //}
    //}
    triggers {
      periodicFolderTrigger {
        interval("1d")
      }
    }
}