build.gradle.kts Gradle Kotlin DSL example

Could you please provide a Gradle example using the Kotlin DSL? I am trying this:

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
import org.jetbrains.kotlin.gradle.dsl.Coroutines

buildscript {
	val kotlin_version = "1.3.10"
	repositories {
		mavenCentral()
	}
	dependencies {
		classpath(kotlin("gradle-plugin", kotlin_version))
		classpath("org.jetbrains.kotlin:kotlin-serialization:$kotlin_version")
	}
}

plugins {
    kotlin("jvm") version "1.3.10"
    "kotlinx-serialization"
}

dependencies {
    compile(kotlin("stdlib-jdk8"))
    compile(kotlin("reflect"))
    testCompile(kotlin("test"))
    testCompile(kotlin("test-junit"))

    compile("com.fasterxml.jackson.module:jackson-module-kotlin:2.9.5")
    testCompile("io.kotlintest:kotlintest-runner-junit5:3.1.7")
    compile("redis.clients:jedis:2.9.0")
    compile("org.jetbrains.kotlinx:kotlinx-serialization-runtime:0.9.0")
}

tasks.withType<KotlinCompile> {
    kotlinOptions {
        jvmTarget = "1.8"
        freeCompilerArgs = listOf("-Xjsr305=strict")
    }
}

repositories {
    mavenCentral()
    maven (url="https://kotlin.bintray.com/kotlinx" )
}

But when I try to compile the example like JSON.stringify(Data.serializer(), Data(42)), I get the error:

e: src/main/kotlin/HelloWorld.kt: (260, 45): Unresolved reference: serializer
> Task :compileKotlin FAILED

FAILURE: Build failed with an exception.

[sandwwraith]

Btw, https://github.com/Kotlin/kotlinx.serialization#gradle-with-plugins-block actually is Gradle Kotlin DSL example so I suppose this can be closed.

[chadmorrow]

Here’s how I got it working:

// settings.gradle.kts

pluginManagement {
    resolutionStrategy {
        eachPlugin {
            if (requested.id.id == "kotlinx-serialization") {
                useModule("org.jetbrains.kotlin:kotlin-serialization:${requested.version}")
            }
        }
    }

    repositories {
        gradlePluginPortal()
        maven("https://kotlin.bintray.com/kotlinx")
    }
}

rootProject.name = "projectName"

and then in the build.gradle.kts file I included it like this:

// build.gradle.kts

plugins {
    kotlin("jvm") version "1.3.40"
    id("kotlinx-serialization") version "1.3.40"
}

dependencies {
    ...
    implementation ("org.jetbrains.kotlinx:kotlinx-serialization-runtime:0.11.1")
    ...
}