ambiguity="explicit" returns None

Describe the bug

When I set ambiguity=“explicit”, it returns None when parsing. Not setting it makes it parse normally

To Reproduce

#!/usr/bin/env python3
# -*- coding: utf-8 -*-
"""
Initial author: Bryan Hu.

The main program that will run.
"""
from pathlib import Path

import lark

here = Path(__file__).parent
lark_grammar = Path(here / "grammar.lark")

parser = lark.Lark(lark_grammar.read_text(), ambiguity="explicit")
DOC = R"""
func main (argv:List<Str>, argc: int) {
    obj Greeter {
        private var _name
        var name: property<Str>
        func init(name: str) -> Void {
            self._name = name
            self.name = property(
                get=(func() -> Str {return self._name})
            )
        }
        func __str__() -> Str {
            return "hello, " + self._name
        }
    }
    if not (len(argv) > 1) {
        print("You gotta give me a name")
    } else {
        var maing: Greeter = Greeter(argv[1])
        print(maing)
    }

}
"""
print(parser.parse(DOC).pretty())

And the very ambiguous, nondeterministic grammar (still trying to reduce ambiguity):

%import common.WS
%import common.NEWLINE
%import common.CNAME -> IDENTIFIER
%import python.STRING
%import common.SIGNED_NUMBER -> NUMBER
%import common.SH_COMMENT -> COMMENT

%ignore WS
%ignore ";"
%ignore NEWLINE
%ignore COMMENT

start: _statement+
////////////////////////////////////////////////////////////////
_statement:  _definition | _operation | _ifs
////////////////////////////////////////////////////////////////
_definition: function_definition | class_definition | variable_definition
// FUNCTION //
function_definition: "func" IDENTIFIER "(" [_sequence{functype, ","}] ")" ["->" _type] braced_code
anonymous_func: "(" "func" "(" [_sequence{functype, ","}] ")" ["->" _type] braced_code ")"
// VARIABLE //
?variable_definition: ("var"|"const") IDENTIFIER ((":" _type) | ([":" _type] "=" value))
// CLASS //
class_definition: "obj" IDENTIFIER [":" NAMESPACABLE] class_code
class_code: "{" (class_defs | _statement)+ "}"

?class_defs: meth_def | class_var_def

?meth_def: [PRIVATE|PUBLIC] function_definition
class_var_def: [PRIVATE|PUBLIC] variable_definition

PRIVATE: "private"
PUBLIC: "public"
////////////////////////////////////////////////////////////////
_operation:  _binary | _logic | _misc | value
// BINARY //
_binary: add
       | sub
       | div
       | mul
       | bor
       | band
       | bnot
       | bxor
add: _bop{"+"}
sub: _bop{"-"}
div: _bop{"/"}
mul: _bop{"*"}
bor: _bop{"|"}
band: _bop{"&"}
bnot: "!" _operation
bxor: _bop{"~"}
// LOGIC //
_logic: gt
      | lt
      | eq
      | not
      | and
      | or
gt: _bop{">"}
lt: _bop{"<"}
eq: _bop{"=="}
and: _bop{"and"}
or: _bop{"or"}
not: "not" _operation
// MISCELLANEOUS //
_misc: assign | return | index | call_op
assign: _bop{"="}
return: "return" [_sequence{value, ","}]
index: value "[" value "]"
call_op: (NAMESPACABLE|anonymous_func) "(" [arguments] ")"

//! PRIVATE !//
_bop{thing}: value thing _operation
arg.2: [IDENTIFIER "=" ] value
arguments: _sequence{arg, ","}  // To prevent clashing with assignment
// FILLER: "..."
////////////////////////////////////////////////////////////////
_ifs: if (elif)* else?
?if: "if" value braced_code
?elif: "else" if
?else: "else" braced_code
////////////////////////////////////////////////////////////////
?value: NAMESPACABLE
      | STRING
      | NUMBER
      | BOOLEAN
      | anonymous_func
      | paranthesised
      | _operation

NAMESPACABLE: /[a-zA-Z_]+(?:\.[0-9a-zA-Z_]+)*/
BOOLEAN: "true" | "false"

braced_code: "{" _statement+ "}" // TODO USE INDENT-BASED

_type: NAMESPACABLE | generic_type
generic_type: NAMESPACABLE "<" _type ">"
functype: (IDENTIFIER ":" _type) ["=" value]
paranthesised.2: "(" value ")"  // Will clash with call-op

_sequence{x, sep}: x (sep x)* sep?

Terminal output:

Traceback (most recent call last):
  File "__main__.py", line 40, in <module>
    print(parser.parse(DOC).pretty())
AttributeError: 'NoneType' object has no attribute 'pretty'

If that is impossible, provide clear steps to reproduce the behavior.

[ThatXliner]

You fixed it. Yep.

@ThatXliner Please verify that latest master version fixes it.

[chanicpanic]

I have a fix for this. I’ll open a PR shortly.