Keywords under Run Keywords are not recognized

Keywords provided as arguments for Run Keywords are not recognized as keywords, thus do not support ‘go to declaration’ feature. I’m using PyCharm 2020.3.5 with RFLS plugin v0.11.1.

[xylix]

Just some of my personal thoughts on the technical side of why this is not exactly simple and why it currently works like it does:

This is of course partially thanks to the type of the upstream objects inputs’ being str and *args instead of the corresponding Keword or function.

https://github.com/robotframework/robotframework/blob/b68e2b689515446056e53edd67bc23c4c1fd8be0/src/robot/libraries/BuiltIn.py#L1856

In general properly typing Robot Framework’s higher order keywords would be quite interesting. And perhaps would also enable auto completion and validation for them when using python LSP when programming Robot.

But fixing it upstream is probably out of scope for Robot LSP. Most likely there are way easier ways to just figure out completion for them keyword-by-keyword for example. Perhaps by using the metadata from the @run_keyword_variant decorator that most such methods have. But that feature is supposed to be deprecated at some point https://github.com/robotframework/robotframework/issues/2190.

[HaaiHenkie]

The same is true for all Builtin keywords that run other keywords. Autocomplete and highlighting is also not supported for keywords that are used as argument.

*** Settings ***
Suite Teardown    Suite Teardown
Test Teardown     Test Teardown

*** Test Cases ***
Keywords running other keywords
    Repeat Keyword    5 times    No Operation
    Run Keyword    No Operation
    Run Keyword And Continue On Failure    No Operation
    Run Keyword And Expect Error    Error    Fail    Error
    Run Keyword And Ignore Error    Fail    Error
    Normal Return
    Conditional Return
    Run Keyword And Return Status    No Operation
    Run Keyword And Warn On Failure    No Operation
    Run Keyword If    ${true}    No Operation
    Run Keyword If    ${true}    No Operation
    ...    ELSE IF    ${true}    Sleep    4s
    ...    ELSE    Fail
    Run Keyword Unless    ${false}    No Operation
    Run Keywords    Sleep    4s
    ...    AND    No Operation
    Wait Until Keyword Succeeds    5s    1s    Sleep    4s

*** Keywords ***
Suite Teardown
    Run Keyword If All Tests Passed    No Operation
    Run Keyword If Any Tests Failed    No Operation

Test Teardown
    Run Keyword If Test Failed    No Operation
    Run Keyword If Test Passed    No Operation
    Run Keyword If Timeout Occurred    No Operation

Normal Return
    Run Keyword And Return    No Operation

Conditional Return
    Run Keyword And Return If    ${true}    No Operation