Translator Error When Using Fluent Functions With DisableMethodInvocation

Receiving an error when using fluent functions in CQL and DisableMethodInvocation is used.

Translator release: 1.5.4

Library:

library ALibrary version '1.0.0'

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.001' called FHIRHelpers
include MATGlobalCommonFunctionsFHIR4 version '6.1.000' called Global

valueset "Diabetes Mellitus": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.3157.1329'

parameter "Measurement Period" Interval<DateTime>

context Patient

define fluent function "confirmed"(Conditions List<Condition>):
  Conditions C where C.verificationStatus ~ Global."confirmed"

define fluent function "active"(Conditions List<Condition>):
  Conditions C where C.clinicalStatus ~ Global."active"
    and C.abatement is null

define fluent function "activeOrRecurring"(Conditions List<Condition>):
  Conditions C
    where C.clinicalStatus ~ Global."active"
      or C.clinicalStatus ~ Global."recurrence"
      or C.clinicalStatus ~ Global."relapse"

define "Diabetes Conditions":
  ["Condition": "Diabetes Mellitus"]

define "Confirmed and Active or Recurring Diabetes Conditions":
  "Diabetes Conditions".confirmed().activeOrRecurring()

Error received: Invalid invocation target: org.hl7.elm.r1.ExprressionRef

Per QMIG STU 2, “This option [DisableMethodInvocation ] should be used with Measures to ensure method-style invocation cannot be used within eCQMs.”

[JSRankins]

Hi @cmoesel , this is in a reference to a specific conversation going on in measure development community. I think you are right, but, if that is the case and we want to support the use of fluent functions in measures (under consideration), then QMIG should probably be updated to provide clarification - either never use DisableMethodInvocation or clarity on how this option works with fluent functions. Authoring tools at that point would have to provide users the ability to toggle that option or be very specific about supporting/not supporting fluent functions. @brynrhodes , thoughts?

[brynrhodes]

The error message here could be better, so I’m going to mark this as an enhancement to improve the error message when accessing a fluent function with the disable method invocation option set.